#!/usr/bin/perl -w

#----------------------------------------------------------------------
# copyright (C) 2000-2001 e-smith, inc.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.	See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307  USA
#
# Technical support for this program is available from e-smith, inc.
# For details, please visit our web site at www.e-smith.com or
# call us on 1 888 ESMITH 1 (US/Canada toll free) or +1 613 564 8000
#----------------------------------------------------------------------

package esmith;

use strict;
use Errno;
use esmith::config;
use esmith::db;
use esmith::util;

tie my %conf, "esmith::config";

my $status = db_get_prop(\%conf, "mysqld", "status");

if (defined $status && $status eq 'enabled')
{

    #----------------------------------------------------------
    # Check to see if MySQL data directory exists
    #----------------------------------------------------------

    if ( -d "/var/lib/mysql/mysql" )
    {
	#----------------------------------------------------------
	# Check to see if mysqld is running. It should be listening
	# on /var/lib/mysql/mysql.sock
	#----------------------------------------------------------

	my $running = 0;

	open(NETSTAT, "-|")
	    or exec qw(/bin/netstat --listening --unix);

	while (<NETSTAT>)
	{
	    if (m#/var/lib/mysql/mysql.sock#)
	    {
		++$running;
		last;
	    }
	}

	close NETSTAT;

	# You can't import the tables if mysqld isn't running!

	exit(0) unless $running;

	#----------------------------------------------------------
	# Read LDAP password
	#----------------------------------------------------------
	my $pw = esmith::util::LdapPassword();

	#----------------------------------------------------------
	# Import MySQL databases
	#----------------------------------------------------------

	if (-f "/home/e-smith/db/mysql/mysql.dump")
	{
	    # Only import data if there is data to import!

	    my $pid = open(KID, "-|");

	    if (defined $pid)
	    {
		if ($pid) # Parent
		{
		    while (<KID>)
		    {
			print;
		    }
		    close KID;
		    waitpid($pid, 0);
		}
		else
		{
		    chdir("/home/e-smith/db/mysql/");
		    open(STDIN,"<mysql.dump");
		    my $command = "/usr/bin/mysql -p$pw";
		    exec($command);
		}
	    }
	    else
	    {
		warn("Couldn't fork: $!");
	    }

	    #----------------------------------------------------------
	    # Reset root password in MySQL database
	    #----------------------------------------------------------

	    #----------------------------------------------------------
	    # set MySQL password based on LDAP password
	    #----------------------------------------------------------

	    $pid = open(KID, "|-");
	    if (defined $pid)
	    {
		if ($pid)
		{
		    print KID "use mysql;\n";
		    print KID "UPDATE user SET password=password(\'$pw\') " .
				"WHERE user='root';\n";
		    print KID "DELETE FROM user WHERE user=''\n";
		    close KID;
		    waitpid $pid,0;
		}
		else
		{
		    exec(qw(/usr/libexec/mysqld
			--bootstrap
			--skip-grant-tables
			--basedir=/usr
			--datadir=/var/lib/mysql));
		}
	    }
	    else
	    {
		warn("Couldn't fork: $!");
	    }

	    untie %conf;

	    esmith::util::serviceControl(
		    NAME   => 'mysqld',
		    ACTION => 'restart'
		)
		    || warn(
				"Couldn't restart MySQL,"
				. " grant tables may need flushing.\n"
			    )
		    && die "Couldn't restart mysqld";
	}
    }
}

exit(0);
